D語言混合型別

混合型別的結構，使所生成的程式碼中混合型別的原始碼。混合型別可以是以下型別。

• String 混合型別

• Template 混合型別

• 混合名稱空間

String 混合型別

D語言有字串在編譯時插入程式碼串的能力。字串混合型別的語法如下所示。

mixin (compile_time_generated_string)

一個簡單字串混合型別的例子如下所示。

import std.stdio;

void main()
{
   mixin(`writeln("Hello World!");`);
}

當上面的程式碼被編譯並執行，它會產生結果如下：

Hello World!

這裡是另一個例子，我們可以通過在字串中的編譯時間，以便混合型別可以使用函式來重用程式碼。它如下所示。

import std.stdio;

string print(string s)
{
   return `writeln("` ~ s ~ `");`;
}

void main()
{
   mixin (print("str1"));
   mixin (print("str2"));
}

當上面的程式碼被編譯並執行，它會產生結果如下：

str1
str2

模板混合型別

D語言模板定義通用的程式碼模式，讓編譯器來生成該模式的實際情況。模板可以生成功能，結構，聯合，類，介面，以及任何其他合法D程式碼。模板混合型別的語法如下所示。

mixin a_template!(template_parameters)

一個簡單的例子字串混合型別如下所示，我們建立一個類系和一個混合型別範例化一個模板一個模板，從而使得該功能的setName和printNames可用的結構college。

import std.stdio;

template Department(T, size_t count)
{
   T[count] names;

   void setName(size_t index, T name)
   {
      names[index] = name;
   }

   void printNames()
   {
      writeln("The names");

      foreach (i, name; names) 
      {
         writeln(i," : ", name);
      }
   }
}

struct College
{
   mixin Department!(string, 2);
}

void main()
{
   auto college = College();

   college.setName(0, "name1");
   college.setName(1, "name2");

   college.printNames();
}

當上面的程式碼被編譯並執行，它會產生結果如下：

The names
0 : name1
1 : name2

混入名稱空間

混入的名稱空間是用來避免在模板中混合型別含糊不清。例如，可以有兩個變數，一個在主顯式定義，而另一個是混合的。當混合在名稱相同的名稱是在周邊範圍內，則認為是在周圍範圍的名稱得到使用。這個例子顯示如下。

import std.stdio;

template Person()
{
   string name;
   void print()
   {
      writeln(name);
   }
}

void main()
{
   string name;

   mixin Person a;

   name = "name 1";
   writeln(name);

   a.name = "name 2";
   print();
}

name 1
name 2