記得朋友圈看到過一句話，如果Defi是以太坊的皇冠，那麼Uniswap就是這頂皇冠中的明珠。Uniswap目前已經是V2版本，相對V1，它的功能更加全面優化，然而其合約原始碼卻並不複雜。本文為個人學習UniswapV2原始碼的系列記錄文章。
該合約為利用UniswapV2交易對中的FlashSwap的先借後還特性，在買賣資產的同時和UnisapV1交易對進行交易，利用價格差進行套利。
pragma solidity =0.6.6;
import '@uniswap/v2-core/contracts/interfaces/IUniswapV2Callee.sol';
import '../libraries/UniswapV2Library.sol';
import '../interfaces/V1/IUniswapV1Factory.sol';
import '../interfaces/V1/IUniswapV1Exchange.sol';
import '../interfaces/IUniswapV2Router01.sol';
import '../interfaces/IERC20.sol';
import '../interfaces/IWETH.sol';
contract ExampleFlashSwap is IUniswapV2Callee {
IUniswapV1Factory immutable factoryV1;
address immutable factory;
IWETH immutable WETH;
constructor(address _factory, address _factoryV1, address router) public {
factoryV1 = IUniswapV1Factory(_factoryV1);
factory = _factory;
WETH = IWETH(IUniswapV2Router01(router).WETH());
}
// needs to accept ETH from any V1 exchange and WETH. ideally this could be enforced, as in the router,
// but it's not possible because it requires a call to the v1 factory, which takes too much gas
receive() external payable {}
// gets tokens/WETH via a V2 flash swap, swaps for the ETH/tokens on V1, repays V2, and keeps the rest!
function uniswapV2Call(address sender, uint amount0, uint amount1, bytes calldata data) external override {
address[] memory path = new address[](2);
uint amountToken;
uint amountETH;
{ // scope for token{0,1}, avoids stack too deep errors
address token0 = IUniswapV2Pair(msg.sender).token0();
address token1 = IUniswapV2Pair(msg.sender).token1();
assert(msg.sender == UniswapV2Library.pairFor(factory, token0, token1)); // ensure that msg.sender is actually a V2 pair
assert(amount0 == 0 || amount1 == 0); // this strategy is unidirectional
path[0] = amount0 == 0 ? token0 : token1;
path[1] = amount0 == 0 ? token1 : token0;
amountToken = token0 == address(WETH) ? amount1 : amount0;
amountETH = token0 == address(WETH) ? amount0 : amount1;
}
assert(path[0] == address(WETH) || path[1] == address(WETH)); // this strategy only works with a V2 WETH pair
IERC20 token = IERC20(path[0] == address(WETH) ? path[1] : path[0]);
IUniswapV1Exchange exchangeV1 = IUniswapV1Exchange(factoryV1.getExchange(address(token))); // get V1 exchange
if (amountToken > 0) {
(uint minETH) = abi.decode(data, (uint)); // slippage parameter for V1, passed in by caller
token.approve(address(exchangeV1), amountToken);
uint amountReceived = exchangeV1.tokenToEthSwapInput(amountToken, minETH, uint(-1));
uint amountRequired = UniswapV2Library.getAmountsIn(factory, amountToken, path)[0];
assert(amountReceived > amountRequired); // fail if we didn't get enough ETH back to repay our flash loan
WETH.deposit{value: amountRequired}();
assert(WETH.transfer(msg.sender, amountRequired)); // return WETH to V2 pair
(bool success,) = sender.call{value: amountReceived - amountRequired}(new bytes(0)); // keep the rest! (ETH)
assert(success);
} else {
(uint minTokens) = abi.decode(data, (uint)); // slippage parameter for V1, passed in by caller
WETH.withdraw(amountETH);
uint amountReceived = exchangeV1.ethToTokenSwapInput{value: amountETH}(minTokens, uint(-1));
uint amountRequired = UniswapV2Library.getAmountsIn(factory, amountETH, path)[0];
assert(amountReceived > amountRequired); // fail if we didn't get enough tokens back to repay our flash loan
assert(token.transfer(msg.sender, amountRequired)); // return tokens to V2 pair
assert(token.transfer(sender, amountReceived - amountRequired)); // keep the rest! (tokens)
}
}
}
第一行，照例是指定Solidity版本
第二行，匯入IUniswapV2Callee介面，該介面定義了一個接收到代幣後的回撥函數。在Uniswapv2核心合約中的交易對合約的swap函數有這麼一行程式碼：
if (data.length > 0) IUniswapV2Callee(to).uniswapV2Call(msg.sender, amount0Out, amount1Out, data);。這正是呼叫了該函數。這行程式碼在使用者得到買入的資產後立即呼叫了，且發生在使用者賣出資產之前。使用者可以在這個空隙利用uniswapV2Call這個回撥函數做自己想做的任意操作，比如說套利等。因此，此回撥函數再加上UniswapV2交易對的先買進再賣出機制是實現套利的核心。
接下來六個import函數分別匯入UniswapV1版本的factory合約介面和交易對介面，V2版的工具庫及Router介面，標準ERC20代幣介面和WETH介面。因為V1版本的交易對為ETH/ERC20交易對，所以V2版本的交易對相應為WETH/ERC20交易對，所以需要用到WETH及ERC20介面。
contract ExampleFlashSwap is IUniswapV2Callee {這一行為合約定義，它必須實現IUniswapV2Callee，也就是必須實現uniswapV2Call這個函數，不然無法進行回撥會報錯重置交易。
IUniswapV1Factory immutable factoryV1;
address immutable factory;
IWETH immutable WETH;
接下來是三個狀態變數，分別為V1版本的factory範例，V2版本的factory地址及WETH的範例。為什麼這裡V2版本的factory為地址型別而不為範例（合約型別）呢？因為下面的IUniswapV2Callee函數會利用該地址進行大量的計算（見工具庫），所以這裡使用地址型別更方便一些。
接下來是constructor構造器，利用輸入引數對上面三個狀態變數初始化。注意，WETH範例的初始化不是直接傳入的WETH合約地址，而是利用Router合約得到的。其實WETH合約人人都可以部署一個，是可以存在多個的。如果存在這種情況，到底用哪個地址範例化呢？用Router合約用到的那個地址才是一致的，是準確無誤的。
receive() external payable {} 這行程式碼代表可以接收直接傳送的ETH，註釋的意思和上一篇文章學習中對應的註釋類似，這裡不再重複了。
uniswapV2Call函數學習uniswapV2Call函數，它的註釋清晰的解釋了套利的過程。這期間你不需要擁有任何一種交易對中的資產（僅需要有少量的ETH來支付gas費用），俗稱空手套白狼。它的四個輸入引數為呼叫者（其實就是最初發起交易的賬號）、從V2交易對傳送過來的兩種資產數量、使用者預先定義的資料。
注意上面提到的V2版本交易對的這行程式碼：
if (data.length > 0) IUniswapV2Callee(to).uniswapV2Call(msg.sender, amount0Out, amount1Out, data);。這就意味著本合約實際上為上述程式碼中的to，也就是說使用者呼叫交易對合約的swap函數時，輸入的接收地址to必須為本合約地址。
下面我們來詳細學習該函數：
path來儲存兩種資產的地址。path是路徑的意思，也可以代表交易路徑（流程）。token0與token1你都不知道是什麼。stack too deep errors，已經講過多次，不再重複。msg.sender就是V2的交易對，因為本函數是從V2交易對呼叫的。見上面列出的那行呼叫程式碼。path[0]為賣出的資產（買進的為0），path[1]為買進的資產，也就是交易路徑為path[0] => path[1]。這裡需要說明，UniswapV2交易對呼叫此函數時提供的輸入引數amount0及amount1是和token0及token1對應的，也就是token0的買進數量為amount0。amountToken數值。如果token0為WETH地址，那麼另一種資產必為TOKEN，所以其數值為amount1；否則就是本資產token0，對應的數值為amount0。amountETH數值。邏輯同上。token0或者token1必須有一個為WETH地址，它們是等效的。註釋講了用來確保它是V2中的包含WETH的交易對（否則無法和V1交易對套利），前面第7行只驗證了必須為V2交易對。factory中的getExchange介面來獲取包含該ERC20代幣（15行那個範例）的交易對地址。if - else語句來根據從UniswapV2交易對得到的是普通ERC20代幣還是ETH分情況和UniswapV1的交易對進行交易，最後將得到的另一種資產支付給UniswapV2交易對，自己留下剩餘的，實現套利的目的。amountToken > 0，那就是從UniswapV2交易對得到了普通ERC20代幣，則接著進行：
data解碼成uint格式，並設定成為minETH的值。這個minETH是在V1交易對交易時指定得到的ETH最小值。這個解碼的語法abi.decode這裡已經是第二次使用了。第一次使用在核心合約中的交易對合約的_safeTransfer函數中：abi.decode(data, (bool))，大家可以自己對照看一下。getAmountsIn函數返回的是一個陣列，它的第一個元素就是賣出的初始資產的數量。具體分析可以參考序列文章中的周邊合約學習中的Router合約學習。assert函數，但是我們有時也會在合約中看到使用require函數驗證。那麼什麼時候用require什麼時候用assert呢？一般的原則為：當驗證直接外界輸入時，使用require；當驗證內部結果時，使用assert。可以看到這裡是驗證中間的一個計算結果，所以使用了assert。msg.sender），這裡就是先借後還的「還」。那什麼時候開始借的呢，從呼叫本函數之前就借給本合約（轉移資產到本合約）了。call，它如果執行失敗，並不會重置整個交易，而是返回一個false，所以這裡必須驗證返回值。這裡為什麼不使用更高階的address型別的transfer或send成員呢。個人猜想原因有：
WETH.transfer這種呼叫語句相區分，可能引起閱讀上的混淆；transfer或send 必須在address payable型別上使用，需要使用payable(sender)來轉換。transfer或send函數限定了隨函數傳輸的gas為2300。萬一接收地址是一個合約，它還需要接收ETH後再做別的事，這時便會引起out of gas，導致交易失敗。使用call可以將所有能得到的gas都傳輸過去，利於接收方再執行其它操作。transfer或send還是call來傳送ETH，接收地址如果是合約的話，必須有相應接收ETH的回撥函數，例如本合約中出現的receive，否則交易會失敗。else，那就是amountETH > 0，也就是從UniswapV2交易對得到的是WETH，需要使用它從V1交易對中兌換出來TOKEN，然後再支付TOKEN給V2版本的交易對。
msg.sender，這裡就是先借後還中的「還」。這裡因為使用了assert函數，所以要求token.transfer必須返回一個true。所以這個TOKEN對應的代幣合約必需滿足這個條件（個人猜想因為代幣合約是外部合約，是未知的，有可能不返回值或者返回為false，所以必須加一個條件）。sender），這裡不用考慮接收方（sender）是合約還是外部賬號，因為不是傳送ETH。使用assert同上。大家從這個合約可以看出，套利合約使用沒有門檻，但它並不意味著我們隨時都可以使用這個套利合約來套利。個人覺得使用條件及限制有：
實際中也有其它DeFi交易對和UniswapV2交易對之間套利的應用，例如DODO這個專案就有一個套利合約UniswapArbitrageur.sol（不過是針對特定交易對的）。大家有興趣的可以自己去看一下。
好了，今天的套利合約範例學習就到此結束了，下一次計劃學習ExampleOracleSimple.sol(價格預言機範例合約)。
由於個人能力有限，難免有理解錯誤或者不正確的地方，還請大家多多留言指正。